93本目 複数ブックを連結して再分割

VBA100本ノック 93本目を動画で解説しています。Excelの神髄さんの模範解答はコチラ

---

問題

#VBA100本ノック 93本目
「月別」フォルダには、同一フォーマット（1シートのみ）の
年月別のファイルがあります。
全データを集め、支店別に分割し直し、
「支店別」フォルダに、「支店CD.xlsx」で出力してください。
フォーマットは画像及びサンプルファイルにて。
※「月別」、「支店別」フォルダのパスは任意

解答

Sub ノック93本目()

    Dim wb As Workbook: Set wb = ThisWorkbook
    Dim ws As Worksheet: Set ws = wb.Sheets(1)
    Dim inPath As String: inPath = wb.Path & "\月別\"
    Dim outPath As String: outPath = wb.Path & "\支店別\"
    Dim fso As New FileSystemObject
    Dim f As File, wb元 As Workbook, ws元 As Worksheet, lastrow As Long
    For Each f In fso.GetFolder(inPath).Files '月別フォルダの全ファイルをループ
        Set wb元 = Workbooks.Open(f.Path, , True) ' ファイルを読み取り専用で開く
        Set ws元 = wb元.Sheets(1)
        If ws.Range("A1") = "" Then 'もしこのwsのA1セルが空白なら
            ws元.Range("A1").CurrentRegion.Copy ws.Range("A1") '先頭含めてコピー
        Else
            lastrow = ws.Cells(Rows.Count, 1).End(xlUp).Row  'wsの最終行を取得
            ws元.Range("A1").CurrentRegion.Offset(1).Copy ws.Range("A" & lastrow + 1) '最終行の一つ下へ
        End If
        wb元.Close False ' 最後は閉じる
    Next
    
    Dim wsリスト As Worksheet: Set wsリスト = Worksheets.Add(after:=Sheets(1)) '支社リスト用シート
    ws.Range("A:A").AdvancedFilter xlFilterCopy, , wsリスト.Range("A1"), True '重複を削除しつつコピー
    
    Dim wb先 As Workbook
    Dim ws先 As Worksheet
    Dim i As Long
    For i = 2 To wsリスト.Cells(Rows.Count, 1).End(xlUp).Row
        Set wb先 = Workbooks.Add
        Set ws先 = wb先.Sheets(1)
        ws.Range("A1").CurrentRegion.AutoFilter 1, wsリスト.Cells(i, 1).Value
        ws.Range("A1").CurrentRegion.Copy ws先.Range("A1")
        wb先.SaveAs outPath & wsリスト.Cells(i, 1).Value & ".xlsx"
        wb先.Close
        ws.AutoFilterMode = False
    Next i
        
End Sub

■考え方・流れ
0:00 冒頭・問題確認
2:20 月別フォルダの全ファイルをまとめる
6:50 支店のリストを作成する
9:04 支社ごとに新規ブックに保存

過去の復習の内容が多かったので一つの章が結構ボリューミーだぞ！

このコードを実行するとこんな感じだ！！

これを実行すると、なんと！見事！すばら！
wsリストにユニークなリストを作ることができたぞ！！

え、AdvancedFilterでよくね？？
どうなんだろ…(疑惑疑惑)

うーん…。
なんでこう書いたか忘れたけど…
アドバンスでいいような気がしてきた…。
なんか理由あったっけ…？？
この動画作ったのもう5か月ぐらい前だからなぁ…

もし誰か理由わかったら教えてwwww

すまん！
よく分からんがお疲れんこん～～～！！

あとがたり

おはこんばんちは。uぷ主です。
93本目！！ブックを分割したりまとめたりなんやかんやしたりする問題でした！

ファイルをまとめる部分のコード(1章部分)だけで、1つの問題ぐらい量あって草。
FSOさんとかForEachさんとかどんだけ使うねんって感じ。

FSOさんは20本目でかな～り濃い目に動画にしたつもりなんですけど…
ForEachさんももっと濃く濃く動画化したほうが良かったかな(今更)
2周目ではちょっとここ検討します。

あと…もしかしたら…AdvancedFilterってノックでは初見？だったかな？
実務で最近使いまくってるんで…初めての気は全くしなかったんですが…

使用シーンは…基本的にはxlFilterCopy+Uniqueをやりたい時。
それ以外は普通にCopyかFilterで何とかしてる気がします。

最近疲れてるのもあり…実務と動画での内容がごっちゃになってて草。
Youtubeが副業に活きてるというか…Youtubeに私生活を殺されてるというか…

とにかく、今回は草生えまくりの解説でしたな～。
申し訳ない。

あと7本。もうちょっとのんびりいきましょうか～。もう年末ですし。